// Destroys any residual Immy in Jonny's dungeon from the .gam file.
IF
	InParty("Imoen2")
	!InParty(Myself)
	Global("hf_Hide_Old_Immy","GLOBAL",0)
THEN
	RESPONSE #100
		SetGlobal("hf_Hide_Old_Immy","GLOBAL",1)
		DestroySelf()
END

IF
	InParty(Myself)
	Global("ImoenRomanceActive","LOCALS",0)
THEN
	RESPONSE #100
		SetGlobal("ImoenRomanceActive","LOCALS",1)
END

IF
	InParty(Myself)
	Global("hf_Original_Imoen_Tag","GLOBAL",0)
THEN
	RESPONSE #100
		SetGlobal("hf_Original_Imoen_Tag","GLOBAL",1)
		Continue()
END

IF
	InParty(Myself)
	AreaCheck("AR0603")
	Detect(Player1)
	Global("beenInHere1","GLOBAL",0)
	Global("IAmCreatedMR","GLOBAL",0)
THEN
	RESPONSE #100
		SetGlobal("beenInHere1","GLOBAL",1)
		SetGlobal("IAmCreatedMR","GLOBAL",1)
		CreateCreature("TALKERMR",[3300.1900],0)
		RealSetGlobalTimer("FirstTimer6MR","GLOBAL",16)
		Continue()
END

IF
	InParty(Myself)
	AreaCheck("AR0603")
	See(Player1)
	!StateCheck(Player1,STATE_SLEEPING)
	Global("beenInHere1","GLOBAL",1)
	RealGlobalTimerExpired("FirstTimer6MR","GLOBAL")
THEN
	RESPONSE #100
		SetGlobal("beenInHere1","GLOBAL",2)
		StartDialog("IMOEN2J",Player1)
END

IF
	G("IAmCreatedMR",1)
	Range("TALKERMR",8)
	G("AtTheExitMR",0)
THEN
	RESPONSE #100
		SG("AtTheExitMR",1)
		Continue()
END

IF
	InParty(Myself)
	AreaCheck("AR0603")
	G("AtTheExitMR",1)
	Detect(Player1)
	IsValidForPartyDialog("Imoen2") //Imoen -> Imoen2 DV
	!StateCheck(Player1,STATE_SLEEPING)
THEN
	RESPONSE #100
		SG("AtTheExitMR",2)
		SG("ExitingDialogWithImoen",1)
		MoveViewPoint([3293.1834],INSTANT)
		StartDialog("IMOEN2J",Player1)
END




