!!ARBvp1.0 OPTION ARB_position_invariant ;

# VPROG_INTERACTION
#
# input:
#
# attrib[8] TEX0	texture coordinates
# attrib[9] TEX1	normal
# attrib[10] TEX2	tangent[0]
# attrib[11] TEX3	tangent[1]
# COL			vertex color
#
# c[4]	localLightOrigin
# c[5]	localViewOrigin
# c[6]	lightProjection S
# c[7]	lightProjection T
# c[8]	lightProjection Q
# c[9]	lightFalloff S
# c[10]	bumpMatrix S
# c[11]	bumpMatrix T
# c[12]	diffuseMatrix S
# c[13]	diffuseMatrix T
# c[14]	specularMatrix S
# c[15]	specularMatrix T
# c[16]	vertex color modulate
# c[17]	vertex color add
#
# output:
#
# texture 0 is the cube map
# texture 1 is the per-surface bump map
# texture 2 is the light falloff texture
# texture 3 is the light projection texture
# texture 4 is the per-surface diffuse map
# texture 5 is the per-surface specular map
# texture 6 is the specular lookup table

TEMP	R0, R1, R2;

PARAM	defaultTexCoord = { 0, 0.5, 0, 1 };

# calculate vector to light in R0
SUB		R0.xyz, program.env[4], vertex.position;

# put into texture space for TEX0
DP3		result.texcoord[0].x, vertex.attrib[9], R0;
DP3		result.texcoord[0].y, vertex.attrib[10], R0;
DP3		result.texcoord[0].z, vertex.attrib[11], R0;

# textures 1 takes the base coordinates by the texture matrix
MOV		result.texcoord[1].xy, defaultTexCoord;
MOV		result.texcoord[1], vertex.attrib[8];
#DP4		result.texcoord[1].x, vertex.attrib[8], program.env[10];
#DP4		result.texcoord[1].y, vertex.attrib[8], program.env[11];

# texture 2 has one texgen
MOV		result.texcoord[2].xy, defaultTexCoord;
DP4		result.texcoord[2].x, vertex.position, program.env[9];

# texture 3 has three texgens
DP4		result.texcoord[3].x, vertex.position, program.env[6];
DP4		result.texcoord[3].y, vertex.position, program.env[7];
DP4		result.texcoord[3].w, vertex.position, program.env[8];

# calculate vector to viewer in R0
SUB		R0.xyz, program.env[5], vertex.position;

# put into texture space for TEX6
DP3		result.texcoord[6].x, vertex.attrib[9], R0;
DP3		result.texcoord[6].y, vertex.attrib[10], R0;
DP3		result.texcoord[6].z, vertex.attrib[11], R0;

END

#==================================================================================

!!ARBfp1.0
OPTION ARB_precision_hint_nicest;

# texture 0 is the cube map
# texture 1 is the per-surface bump map
# texture 2 is the light falloff texture
# texture 3 is the light projection texture
# texture 4 is the per-surface diffuse map
# texture 5 is the per-surface specular map
# texture 6 is the specular lookup table

# env[0] is the diffuse modifier
# env[1] is the specular modifier

TEMP	toLight, light, toViewer, halfAngle, color, R1, R2, localNormal;
TEMP	sss;

PARAM	subOne = { -1, -1, -1, -1 };
PARAM	scaleTwo = { 2, 2, 2, 2 };

ALIAS	spec = halfAngle;

#
# the amount of light contacting the fragment is the
# product of the two light projections and the surface
# bump mapping
#

# normalize the direction to the light
DP3		toLight, fragment.texcoord[0],fragment.texcoord[0];
RSQ		toLight, toLight.x;
MUL		toLight.xyz, toLight.x, fragment.texcoord[0];

# normalize the direction to the viewer
DP3		toViewer, fragment.texcoord[6],fragment.texcoord[6];
RSQ		toViewer, toViewer.x;
MUL		toViewer.xyz, toViewer.x, fragment.texcoord[6];

# load the filtered normal map
TEX		localNormal, fragment.texcoord[1], texture[1], 2D;
MOV		localNormal.x, localNormal.a;
MOV   localNormal.z, 0.99;
MAD		localNormal.xyz, localNormal, scaleTwo, subOne;

# soften
LRP		localNormal, program.local[6].x, toViewer, localNormal;

# localNormal filter
MOV	R1.xyz, localNormal;
MOV	R1.z, 0.0;
DP3_SAT	R1, R1, R1;
MAD_SAT	R1.z, R1.w, -1, 1;
RSQ	R1, R1.z;
RCP	localNormal.z, R1.w;

# localNormal filter
#MOV		localNormal.z, 0;
#DP3_SAT	R1.x, localNormal,localNormal;
#ADD_SAT	R1.x, 1, -R1.x;
#RSQ		R1.x, R1.x;
#RCP		localNormal.z, R1.x;

# localNormal filter
ADD	R1, fragment.texcoord[1], 0.5;
TXB	R2, R1, texture[1], 2D;
MOV R2.x, R2.a;
MAD	R2, R2, scaleTwo, subOne;

#TEX		localNormal, localNormal, texture[0], CUBE;
#MAD		localNormal, localNormal, scaleTwo, subOne;

# normalize the bumpmap
#DP3		R1, localNormal,localNormal;
#RSQ		R1, R1.w;
#MUL		localNormal.xyz, R1.w, localNormal;

# normalize the bumpmap
DP3		R1, localNormal,localNormal;
RSQ		R1, R1.x;
MUL		localNormal.xyz, localNormal, R1.x;

# diffuse dot product
DP3		light, toLight, localNormal;

# modulate by the diffuse map
TEX		color.xyz, fragment.texcoord[1], texture[4], 2D;
MUL		color.xyz, light, color;

# calculate the half angle vector and normalize
ADD		halfAngle.xyz, toLight, toViewer;
DP3		R1.xyz, halfAngle, halfAngle;
RSQ		R1, R1.x;
MUL		halfAngle.xyz, halfAngle, R1;

# calculate specular
DP3_SAT		spec.xyz, halfAngle, localNormal;			#spec: x=spec, y=side spec

POW_SAT		spec.x, spec.x, program.local[4].w;		# spec

POW		spec.y, spec.y, program.local[5].w;		# glancing spec
DP3		R2, localNormal, toViewer;
SUB		R2, 1.0, R2;
POW_SAT	R2, R2.x, program.local[3].x;
MUL		spec.y, R2, spec.y;

# modulate by the constant specular factor
MUL		R1, spec.y, program.local[5];
MUL		spec.xyz, spec.x, program.local[4];

# modulate by the specular map
TEX		R2, fragment.texcoord[1], texture[5], 2D;
MAD		color.xyz, spec, R2, color;

# modulate by the glancing specular map
TEX		R2, fragment.texcoord[1], texture[6], 2D;
MAD		color.xyz, R1, R2, color;

#sss
MAD_SAT	sss, light, program.local[2].x, program.local[2].y;	# wrap
MAD		sss, sss, -sss, sss;	# (1-sss)*sss with wrap instead of abs on inv
MUL		sss, sss, program.local[1];
MUL		R1, light, light;
MAD		sss, -R1, sss, sss;
ADD		color.xyz, sss, color;

# self shadow
DP3		R2, toLight, localNormal;
MAD_SAT R2, 1.5, R2, 0.25;
MUL 	color.xyz, color, R2;

# modulate by the light projection
TXP		R1, fragment.texcoord[3], texture[3], 2D;
MUL		color.xyz, color, R1;

# modulate by the light falloff
TXP		R1, fragment.texcoord[2], texture[2], 2D;
MUL		color.xyz, color, R1;

# mask
TEX		R1, fragment.texcoord[1], texture[7], 2D;
DP4		R1, R1, program.local[0];
MUL		color.xyz, color, R1;

MUL		result.color.xyz, color, program.env[0];

END
