//default
windowDef Desktop
{
	rect	0,0,640,480
	visible	1
	nocursor	1
	menugui	0
	
//-----------------------		
// floats and defines
//-----------------------		
	
	definevec4	"ws_on"			1,0.5,0,1
	definevec4	"ws_off"		0.658,0.639,0.376,0.6
	definevec4 	"ws_glowon" 		0.7,0.8,0.5,1
	definevec4 	"ws_glowoff" 		0.7,0.8,0.5,0
	definevec4	"ws_grey"		0.190,0.284,0.168,0.6	
	definevec4 	"typecolor" 		0.866,0.921,0.764,1
	definevec4 	"typecolor_strogg" 	0.988,1,0.784,1
	definevec4	"healthicon"		0.658,0.639,0.376,0.6
	definevec4	"armoricon"		0.658,0.639,0.376,0.6
	definevec4	"healthicon_mp"		0.980,0.168,0.0196,0.8
	definevec4	"armoricon_mp"		0.968,0.752,0.0156,0.8
	definevec4 	"white" 		1,1,1,1
		
	float	"objdone"		0
	float	"weapswitch"	0
	float	"teamstrogg" 	0
	float	"hidden"	0
	
	definefloat	"showGunInfo"	1
	definefloat	"switchLeft"	(640 - (("gui::weaponcount" * 30) - 2)) / 2
	
//-----------------------		
// init and namedevents
//-----------------------		
	
	onInit {
		namedEvent "updateHealth";
		namedEvent "updateArmor";
		namedEvent "updateAmmo";		
		namedEvent "clipCheck";
		namedEvent "updatePowerups";
		namedEvent "hideBrackets";
		namedEvent "weaponChange";
		namedEvent "radioChatterDown";
	}
	
	onNamedEvent hideHud {
		set "desktop::hidden" "1" ;
		set "p_ammo::visible" "0" ;
		set "p_armor::visible" "0" ;
		set "p_health::visible" "0" ;
		set "p_weapswitch::visible" "0" ;
		set "powerups::visible" "0" ;		
	}
	
	onNamedEvent showHud {
		set "desktop::hidden" "0" ;
		set "p_ammo::visible" "1" ;
		set "p_armor::visible" "1" ;
		set "p_health::visible" "1" ;
		set "p_weapswitch::visible" "1" ;
		set "powerups::visible" "1" ;	
	}
	
	onNamedEvent updateHealth {
		if ( "gui::mp" == 0 )
		{
			if ( "gui::player_healthpct" < 0.26 )
			{
				set "health_valbar::matcolor" "1,0.3,0,0.35" ;
				set "health_val::matcolor" "1,0.3,0,0.5" ;
				set "health_ekg::matcolor" "0.3,0.05,0,1" ;
				set "health_backbar_add::visible" "1" ;
			} else	{
				set "health_valbar::matcolor" "0.698,0.811,0.427,0.2" ;
				set "health_val::matcolor" "0.698,0.811,0.427,0.35" ;
				set "health_ekg::matcolor" "0.0862,0.105,0.0549,1" ;
				set "health_backbar_add::visible" "0" ;
			}	
		} else {
			if ( "gui::player_healthpct" < 0.26 )
			{
				set "health_backbar_add_mp::visible" "1" ;
			} else	{
				set "health_backbar_add_mp::visible" "0" ;
			}	
		}
	
		if ( "gui::player_healthdelta" < 0 )
		{
			resettime "health_amount" "0" ;
		}
	}
	
	onNamedEvent updateArmor {
		if ( "gui::player_armordelta" < 0 )
		{
			resettime "armor_amount" "0" ;
		}
	}
	
// Not used currently
//	
//	onNamedEvent updateAmmo {
//		if ( "gui::player_ammodelta" < 0 )
//		{
//			resettime "ammo_amount" "0" ;
//		}
//	}	
	
	onNamedEvent weaponChange {
		namedEvent "clipCheck";
		
//-----------------------
// per weapon ammo bar colors for mp		
//-----------------------
		if ( "gui::mp" == 1 ) {
			if ( "gui::player_weapon" == 0 ) {
				set "ammo_valbar_mp::matcolor" "0,0.85,1,0.2" ;
				set "ammo_val_mp::matcolor" "0,0.85,1,0.5" ;
			} else if ( "gui::player_weapon" == 1 ) {
				set "ammo_valbar_mp::matcolor" "1,1,0,0.2" ;
				set "ammo_val_mp::matcolor" "1,1,0,0.5" ;
			} else if ( "gui::player_weapon" == 2 ) {
				set "ammo_valbar_mp::matcolor" "1,0.55,0,0.2" ;
				set "ammo_val_mp::matcolor" "1,0.55,0,0.5" ;
			} else if ( "gui::player_weapon" == 3 ) {
				set "ammo_valbar_mp::matcolor" "0,0.45,1,0.2" ;
				set "ammo_val_mp::matcolor" "0,0.45,1,0.5" ;
			} else if ( "gui::player_weapon" == 4 ) {
				set "ammo_valbar_mp::matcolor" "0.2,0.56,0.07,0.2" ;
				set "ammo_val_mp::matcolor" "0.2,0.56,0.07,0.5" ;
			} else if ( "gui::player_weapon" == 5 ) {
				set "ammo_valbar_mp::matcolor" "0.6,0.8,0.8,0.2" ;
				set "ammo_val_mp::matcolor" "0.6,0.8,0.8,0.5" ;
			} else if ( "gui::player_weapon" == 6 ) {
				set "ammo_valbar_mp::matcolor" "1,0.25,0,0.2" ;
				set "ammo_val_mp::matcolor" "1,0.25,0,0.5" ;
			} else if ( "gui::player_weapon" == 7 ) {
				set "ammo_valbar_mp::matcolor" "0,1,0,0.2" ;
				set "ammo_val_mp::matcolor" "0,1,0,0.5" ;
			} else if ( "gui::player_weapon" == 8 ) {
				set "ammo_valbar_mp::matcolor" "1,1,0.6,0.2" ;
				set "ammo_val_mp::matcolor" "1,1,0.6,0.5" ;
			} else if ( "gui::player_weapon" == 9 ) {
				set "ammo_valbar_mp::matcolor" "0.77,0.2,1,0.2" ;
				set "ammo_val_mp::matcolor" "0.77,0.2,1,0.5" ;
			}
		}
		
//-----------------------		
// If we had a valid weapon as out last weapon then show the weapon 
// switch icons.  This check prevents the indicators from coming up
// when you first start the game.
//-----------------------	

		set "p_weapswitch::visible" "0";
		if ( "gui::player_lastweapon" >= 0 && "desktop::hidden" == 0)
		{
			namedEvent "p_weapswitch::UpdateWeapons";
			set "p_weapswitch::visible" "1";
			set "desktop::weapswitch" "1";
			resettime "p_weapswitch" "0";
		}					
	}
	
	onNamedEvent weaponFire {
		set "p_weapswitch::visible" "0";
	}	
	
	onNamedEvent clipCheck {
		if ( "gui::player_totalammo" == -1 ) {
			set "ammo_amount::visible" "0";	
			set "ammo_amount_mp::visible" "0";
			set "total_ammo::visible" "0";		
			set "ammo_amount_nc::visible" "0";
		} else if ( "gui::player_ammo" == -1 || "gui::player_clip_size" < 2 ) {
			set "ammo_amount::visible" "0";	
			set "ammo_amount_mp::visible" "1";
			set "total_ammo::visible" "0";	
			set "ammo_amount_nc::visible" "1";
		} else {
			set "ammo_amount_mp::visible" "1";
			set "ammo_amount::visible" "1";	
			set "total_ammo::visible" "1";	
			set "ammo_amount_nc::visible" "0";
		}
	}	
	
	onNamedEvent itemPickup {
		set "p_itempickup::visible" "1" ;
		resettime "p_itempickup" "0" ;
	}		
	
	onNamedEvent radioChatterUp {
		set "p_radio::visible" "1" ;
		
		transition "rhino::rect" "$rhino::rect" "$d_rhino::rect" "500" ;
		transition "rhino_backbar::rect" "$rhino_backbar::rect" "$d_rhino_backbar::rect" "500" ;
	}

	onNamedEvent radioChatterDown {
		set "p_radio::visible" "0" ;
	}
	
	onNamedEvent showBrackets {
		set "brackets::alpha" "1";
		set "brackets::visible" "1";
		stopTransitions "brackets";
		resetTime "brackets" "0";
		set "brackets::notime" "1";
	}
	
	onNamedEvent fadeBrackets {
		resetTime "brackets" "0";
	}

	onNamedEvent hideBrackets {
		stopTransitions "brackets";
		resetTime "brackets" "0";
		set "brackets::notime" "1";
		set "brackets::visible" "0";
	}
	
	onNamedEvent playerHit {
		resetTime "hit_indicator" "0";	
	}
	
	onNamedEvent clearPowerups {
		set "gui::powerup0_visible" "0";
		set "gui::powerup1_visible" "0";
		set "gui::powerup2_visible" "0";
		set "gui::powerup3_visible" "0";
		set "gui::powerup4_visible" "0";
		set "gui::powerup_flag_visible" "0";
	}	
	
	onNamedEvent fadeout {
		resettime "anim_fade" "0" ;
	}	
	
	onNamedEvent resetfade {
		set "fade::backcolor" "0,0,0,0" ;
		set "failedtext::forecolor" "0,0,0,0" ;
	}	
	
	onNamedEvent showBossBar {
		set "BossBar::visible" "1";
	}

	onNamedEvent hideBossBar {
		set "BossBar::visible" "0";
	}	
	
	onNamedEvent showBossShieldBar {
		set "p_boss_shield_bar_left::visible" "1";
		set "p_boss_shield_bar_right::visible" "1";
	}

	onNamedEvent hideBossShieldBar {
		set "p_boss_shield_bar_left::visible" "0";
		set "p_boss_shield_bar_right::visible" "0";
	}	

	onNamedEvent showBossShieldWarn {
		set "p_boss_shield_bar_leftwarn::visible" "1";
		set "p_boss_shield_bar_rightwarn::visible" "1";
		set "p_boss_shield_bar_left::visible" "0";
		set "p_boss_shield_bar_right::visible" "0";
	}

	onNamedEvent hideBossShieldWarn {
		set "p_boss_shield_bar_leftwarn::visible" "0";
		set "p_boss_shield_bar_rightwarn::visible" "0";
		set "p_boss_shield_bar_left::visible" "1";
		set "p_boss_shield_bar_right::visible" "1";
	}	
	
	onNamedEvent showExit {
		set "p_exit_level::visible" "1";
		resettime "anim_levelExitAlert" "0";
	}

	onNamedEvent hideExit {
		set "p_exit_level::visible" "0";
	}	
	
	onNamedEvent setTeam_marine {	
		set "health_valbar_mp::matcolor" "0.698,0.811,0.427,0.2" ;
		set "health_val_mp::matcolor" "0.698,0.811,0.427,0.5" ;
		
		set "armor_valbar_mp::matcolor" "0.698,0.811,0.427,0.2" ;
		set "armor_val_mp::matcolor" "0.698,0.811,0.427,0.5" ;
		
		set "powerup_flag_icon::matcolor" "1,0.482,0.0156,0.8";
		
		set "desktop::teamstrogg" "0" ;
	}	
	
	onNamedEvent setTeam_strogg {	
		set "health_valbar_mp::matcolor" "1,0.5,0,0.2" ;
		set "health_val_mp::matcolor" "1,0.5,0,0.5" ;
		
		set "armor_valbar_mp::matcolor" "1,0.5,0,0.2" ;
		set "armor_val_mp::matcolor" "1,0.5,0,0.5" ;
		
		set "powerup_flag_icon::matcolor" "0.415,0.643,0.168,0.8";
		
		set "desktop::teamstrogg" "1" ;
	}	
	
	onNamedEvent enterFlatbed
	{
		set "p_flatbed::visible" "1";
		set "p_ammo::visible" "0";
		set "p_health::visible" "0";
		set "p_armor::visible" "0";
	}
		
	onNamedEvent leaveFlatbed
	{
		set "p_flatbed::visible" "0";
		set "p_ammo::visible" "1";
		set "p_health::visible" "1";
		set "p_armor::visible" "1";
	}	
		
	onNamedEvent saveMessage {
		set "quicksave_msg::forecolor_w" "1" ;
		set "quicksave_msg::visible" "1" ;
		resettime "quicksave_msg" "0" ;
	}
	
	onNamedEvent missileThreatUp {
		set "missile_indicator::visible" "1";
		resetTime "missile_indicator" "0";	
		
		set "missile_text::visible" "1";
		resetTime "missile_text" "0";	
	}

	onNamedEvent missileThreatDown {
		set "missile_indicator::visible" "0";
		stoptransitions "missile_indicator";	
		set "missile_indicator::matcolor" "1,.1,.1,.7" ;
		
		set "missile_text::visible" "0";
		stoptransitions "missile_text";	
		set "missile_text::forecolor" "1,.1,.1,.7" ;
	}
		
//-----------------------
//  Comment controller - dev only
//-----------------------
	onNamedEvent showViewComments {
		set "ViewComments::visible" "1";
	}
	
	onNamedEvent hideViewComments {
		set "ViewComments::visible" "0";
	}

	windowDef ViewComments {
		rect 2, 5, 638, 200
		backcolor 0, 0, 0, 0
		forecolor 0.9, 0.9, 0.0, 0.9
		visible 0
		textscale 0.25
		text	"gui::viewcomments"
	}
	
//-----------------------
// Sound Meter - Dev Only 
//-----------------------
	windowDef BgSOUND {
		rect	0 ,0 ,128 ,64
		background	"gfx/guis/soundmeter/audiobg"
		matcolor	1 ,1 ,1 ,1 
		visible	("gui::s_debug" == 1)
	}
	windowDef OverlaySOUND {
		rect	0 ,0 ,128 ,64
		background	"gfx/guis/soundmeter/audioverlay"
		matcolor	1 ,1 ,1 ,1
		visible	0
	}
		
//-----------------------		
// flatbed truck health
//-----------------------
		
	windowDef p_flatbed
	{
		rect	0,0,640,480
		visible	0
		windowDef flatbed_backbar
		{
			rect	13,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef p_flatbed_val
		{
			rect	133 - ( "gui::vehicle_health" * 115 ),430,115,40
			visible	1
			shear	0,-.22
			windowDef flatbed_val
			{
				rect	-116 + ( "gui::vehicle_health" * 115 ),0,118,40
				visible	1
				background	"gfx/guis/hud/flatbedbar"
				matcolor	0.701,0.815,0.431,0.35
				shear	0,-.22
			}
		}
		windowDef flatbed_valbar
		{
			rect	17,430,118,40
			visible	1
			background	"gfx/guis/hud/flatbededge"
			matcolor	0.701,0.815,0.431,0.4
			shear	0,-.22
		}
		windowDef tramheat_backbar
		{
			rect	143,429,220,48
			visible	0
			background	"gfx/guis/hud/veh_backbar2"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef tramheat_mgun
		{
			rect	237,449,38,20
			background	"gfx/guis/vehicles/veh_mgun"
			visible	0
			matcolor	0.701,0.815,0.431,0.6
			shear	0,-.22
			matscalex	-1
		}
		windowDef tramheat_valbar_bg
		{
			rect	147,430,110,43
			visible	0
			//visible	("gui::tram_overheat" == 0)
			background	"gfx/guis/hud/veh_backbar2a"
			matcolor	0.976,0.756,0.0156,0.298
			shear	0,-.22
		}
		windowDef p_ammo_valbar
		{
			rect	151,430,"gui::tram_heatpct" * 86,43
			visible	0
			//visible	("gui::tram_overheat" == 0)
			shear	0,-.22
			windowDef tramheat_valbar
			{
				rect	-4,0,110,43
				visible	1
				background	"gfx/guis/hud/veh_backbar2a"
				matcolor	0.980,0.760,0.0196,0.5
				shear	0,-.22
			}
		}
		windowDef tramheat_valbar_bg_oh
		{
			rect	147,430,110,43
			visible	0
			//visible	("gui::tram_overheat" == 1)
			background	"gfx/guis/hud/veh_backbar2a"
			matcolor	1,0.5,0,0.3*guitable_10_5[time*0.002]
			shear	0,-.22
		}
		windowDef p_ammo_valbar_oh
		{
			rect	151,430,"gui::tram_heatpct" * 86,43
			visible	0
			//visible	("gui::tram_overheat" == 1)
			shear	0,-.22
			windowDef tramheat_valbar_oh
			{
				rect	-4,0,110,43
				visible	1
				background	"gfx/guis/hud/veh_backbar2a"
				matcolor	1,0.5,0,0.5*guitable_10_5[time*0.002]
				shear	0,-.22
			}
		}
		windowDef t_tramheat
		{
			rect	152,433,81,10
			visible	0
			forecolor	1,1,1,0.4
			text	"#str_200978"
			textscale	0.12
			font	"fonts/lowpixel"
		}
	}	
	
//-----------------------		
// ammo
//-----------------------		

	windowDef p_ammo
	{
		rect	0,0,640,480
		visible	("gui::mp" == 0 )
		windowDef ammo_backbar
		{
			rect	13,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef ammo_valbar
		{
			rect	13,420,125,59
			visible	1
			background	"gfx/guis/hud/valbar"
			matcolor	0.701,0.815,0.431,0.2
			shear	0,-.22
		}
		
		windowDef p_ammo_val
		{
			rect	133 - ( "gui::player_ammopct" * 115 ),420,115,59
			visible	1
			shear	0,-.22
			windowDef ammo_val
			{
				rect	-120 + ( "gui::player_ammopct" * 115 ),0,125,59
				visible	1
				background	"gfx/guis/hud/valbar"
				matcolor	0.701,0.815,0.431,0.35
				shear	0,-.22
			}
		}
		windowDef current_gun
		{
			rect	11,435,106,26
			visible	"desktop::showGunInfo" != 0
			background	"gui::weapicon"
			matcolor	0.780,0.741,0.470,0.4
		}		
		windowDef ammo_amount
		{
			rect	44,429,49,26
			visible	1
			forecolor	0.866,0.921,0.764,1
			text	"gui::player_ammo"
			textscale	0.5
			font	"fonts/chain"
			shear	0,-.22
			textalign	2
		}
		windowDef total_ammo
		{
			rect	91,432,40,18
			visible	1
			forecolor	0.866,0.921,0.764,1
			text	"gui::player_totalammo"
			textscale	0.32
			font	"fonts/chain"
			shear	0,-.22
			textalign	2
		}
		windowDef ammo_amount_nc
		{
			rect	82,429,49,26
			visible	0
			forecolor	0.866,0.921,0.764,1
			text	"gui::player_totalammo"
			textscale	0.5
			font	"fonts/chain"
			shear	0,-.22
			textalign	2
		}	
		windowDef icon_ammoweapon
		{
			rect	113,458,16,16
			visible	1
			background	"gui::ammoicon"
			matcolor	0.658,0.639,0.376,0.6
		}
	}
	
//-----------------------		
// health
//-----------------------		
	
	windowDef p_health
	{
		rect	0,0,640,480
		visible	("gui::mp" == 0 )
		windowDef health_backbar
		{
			rect	190,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef health_valbar
		{
			rect	190,420,125,59
			visible	1
			background	"gfx/guis/hud/valbar"
			matcolor	0.701,0.815,0.431,0.2
			shear	0,-.22
		}
		windowDef health_ekg
		{
			rect	190,420,125,59
			visible	1
			background	"gfx/guis/hud/ekg"
			matcolor	0.0862,0.105,0.0549,1
			shear	0,-.22
		}
		windowDef p_health_val
		{
			rect	310 - ( "gui::player_healthpct" * 115 ),420,115,59
			visible	1
			shear	0,-.22
			windowDef health_val
			{
				rect	-120 + ( "gui::player_healthpct" * 115 ),0,125,59
				visible	1
				background	"gfx/guis/hud/valbar"
				matcolor	0.701,0.815,0.431,0.35
				shear	0,-.22
			}
		}
		windowDef d_health_amount
		{
			rect	254,427,58,31
			visible	0
		}		
		windowDef health_amount
		{
			rect	256,429,52,26
			visible	1
			forecolor	0.866,0.921,0.764,1
			text	"gui::player_health"
			textscale	0.5
			font	"fonts/chain"
			shear	0,-.22
			textalign	2
			notime	1
			
			onTime 0
			{
				transition "forecolor" "$desktop::white" "$desktop::typecolor" "250" ;
				transition "rect" "$d_health_amount::rect" "$health_amount::rect" "250" ;
				transition "textscale" "0.6" "0.5" "250" ;
				
				transition "icon_health::matcolor" "$desktop::white" "$desktop::healthicon" "250" ;
			}
		}
		windowDef icon_health
		{
			rect	288,458,16,16
			visible	1
			background	"gfx/guis/hud/icons/item_health"
			matcolor	0.658,0.639,0.376,0.6
		}
		windowDef health_backbar_add
		{
			rect	190,420,125,59
			visible	0
			background	"gfx/guis/hud/backbar_add"
			matcolor	1*guitable_10_5[time*0.002],0,0,1
			shear	0,-.22
		}
	}
	
//-----------------------		
// armor
//-----------------------		
	
	windowDef p_armor
	{
		rect	0,0,640,480
		visible	("gui::player_armor" > 0 && "gui::mp" == 0 )
		windowDef armor_backbar
		{
			rect	326,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef armor_valbar
		{
			rect	326,420,125,59
			visible	1
			background	"gfx/guis/hud/arbar"
			matcolor	0.698,0.811,0.427,0.2
			shear	0,-.22
		}
		windowDef p_armor_val
		{
			rect	446 - ( "gui::player_armorpct" * 115 ),420,115,59
			visible	1
			shear	0,-.22
			windowDef armor_val
			{
				rect	-120 + ( "gui::player_armorpct" * 115 ),0,125,59
				visible	1
				background	"gfx/guis/hud/arbar"
				matcolor	0.698,0.811,0.427,0.349
				shear	0,-.22
			}
		}
		windowDef d_armor_amount
		{
			rect	390,427,58,31
			visible	0
		}
		windowDef armor_amount
		{
			rect	392,429,52,26
			visible	1
			forecolor	0.866,0.921,0.764,1
			text	"gui::player_armor"
			textscale	0.5
			font	"fonts/chain"
			shear	0,-.22
			textalign	2
			notime	1
			
			onTime 0
			{
				transition "forecolor" "$desktop::white" "$desktop::typecolor" "250" ;
				transition "rect" "$d_armor_amount::rect" "$armor_amount::rect" "250" ;
				transition "textscale" "0.6" "0.5" "250" ;
				
				transition "icon_armorvest::matcolor" "$desktop::white" "$desktop::armoricon" "250" ;
			}
		}
		
		
		windowDef icon_armorvest
		{
			rect	424,458,16,16
			visible	1
			background	"gfx/guis/hud/icons/item_armor"
			matcolor	0.658,0.639,0.376,0.6
		}
	}

//-----------------------		
// MP ammo
//-----------------------		

	windowDef p_ammo_mp
	{
		rect	0,0,640,480
		visible	("gui::mp" == 1 )
		windowDef ammo_backbar_mp
		{
			rect	13,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef ammo_valbar_mp
		{
			rect	13,420,125,59
			visible	1
			background	"gfx/guis/hud/valbar"
			matcolor	0.5,0.5,0.5,0.2
			shear	0,-.22
		}
		
		windowDef p_ammo_val_mp
		{
			rect	133 - ( "gui::player_ammopct" * 115 ),420,115,59
			visible	1
			shear	0,-.22
			windowDef ammo_val_mp
			{
				rect	-120 + ( "gui::player_ammopct" * 115 ),0,125,59
				visible	1
				background	"gfx/guis/hud/valbar"
				matcolor	0.5,0.5,0.5,0.5
				shear	0,-.22
			}
		}
	
		windowDef ammo_amount_mp
		{
			rect	81,429,50,26
			visible	1
			forecolor	1,1,1,1
			text	"gui::player_totalammo"
			textscale	0.5
			font	"fonts/chain"
			shear	0,-.22
			textalign	2
			textstyle	1
		}	
		windowDef icon_ammoweapon_mp
		{
			rect	113,458,16,16
			visible	1
			background	"gui::ammoicon"
			matcolor	1,1,1,1
		}
	}
//-----------------------		
// MP health
//-----------------------		
	
	windowDef p_health_mp
	{
		rect	0,0,640,480
		visible	("gui::mp" == 1 )
		windowDef health_backbar_mp
		{
			rect	190,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef health_valbar_mp
		{
			rect	190,420,125,59
			visible	1
			background	"gfx/guis/hud/valbar"
			matcolor	0.701,0.815,0.431,0.2
			shear	0,-.22
		}
		windowDef health_ekg_mp
		{
			rect	190,420,125,59
			visible	1
			background	"gfx/guis/hud/ekg"
			matcolor	0.0862,0.105,0.0549,1
			shear	0,-.22
		}
		windowDef p_health_val_mp
		{
			rect	310 - ( "gui::player_healthpct" * 115 ),420,115,59
			visible	1
			shear	0,-.22
			windowDef health_val_mp
			{
				rect	-120 + ( "gui::player_healthpct" * 115 ),0,125,59
				visible	1
				background	"gfx/guis/hud/valbar"
				matcolor	0.701,0.815,0.431,0.5
				shear	0,-.22
			}
		}
		windowDef d_health_amount_mp
		{
			rect	254,427,58,31
			visible	0
		}
		windowDef health_amount_mp
		{
			rect	258,429,50,26
			visible	1
			forecolor	1,1,1,1
			text	"gui::player_health"
			textscale	0.5
			shear	0,-.22
			textalign	2
			notime	1
			textstyle	1

			onTime 0 {
				if ( "desktop::teamstrogg" == 0 )
				{
					transition "forecolor" "$desktop::white" "$desktop::typecolor" "250" ;
				} else	{
					transition "forecolor" "$desktop::white" "$desktop::typecolor_strogg" "250" ;
				}
				transition "rect" "$d_health_amount::rect" "$health_amount::rect" "250" ;
				transition "textscale" "0.6" "0.5" "250" ;
				
				transition "icon_health::matcolor" "$desktop::white" "$desktop::healthicon_mp" "250" ;
			}

		}
		windowDef icon_health_mp
		{
			rect	288,458,16,16
			visible	1
			background	"gfx/guis/hud/icons/item_health"
			matcolor	0.968,0.752,0.0156,0.8
		}
		windowDef health_backbar_add_mp
		{
			rect	190,420,125,59
			visible	0
			background	"gfx/guis/hud/backbar_add"
			matcolor	1*guitable_10_5[time*0.002],0,0,1
			shear	0,-.22
		}
	}
	
//-----------------------		
// MP armor
//-----------------------		
	
	windowDef p_armor_mp
	{
		rect	0,0,640,480
		visible	("gui::player_armor" > 0 && "gui::mp" == 1 )
		windowDef armor_backbar_mp
		{
			rect	326,420,125,59
			visible	1
			background	"gfx/guis/hud/backbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef armor_valbar_mp
		{
			rect	326,420,125,59
			visible	1
			background	"gfx/guis/hud/arbar"
			matcolor	0.698,0.811,0.427,0.2
			shear	0,-.22
		}
		windowDef p_armor_val_mp
		{
			rect	446 - ( "gui::player_armorpct" * 115 ),420,115,59
			visible	1
			shear	0,-.22
			windowDef armor_val_mp
			{
				rect	-120 + ( "gui::player_armorpct" * 115 ),0,125,59
				visible	1
				background	"gfx/guis/hud/arbar"
				matcolor	0.698,0.811,0.427,0.5
				shear	0,-.22
			}
		}
		windowDef d_armor_amount_mp
		{
			rect	388,426,60,34
			visible	0
		}
		windowDef armor_amount_mp
		{
			rect	394,429,50,26
			visible	1
			forecolor	1,1,1,1
			text	"gui::player_armor"
			textscale	0.5
			shear	0,-.22
			textalign	2
			notime	1
			textstyle	1

			onTime 0 {
				if ( "desktop::teamstrogg" == 0 )
				{
					transition "forecolor" "$desktop::white" "$desktop::typecolor" "250" ;
				} else	{
					transition "forecolor" "$desktop::white" "$desktop::typecolor_strogg" "250" ;
				}
				transition "rect" "$d_armor_amount::rect" "$armor_amount::rect" "250" ;
				transition "textscale" "0.6" "0.5" "250" ;
				
				transition "icon_armorvest::matcolor" "$desktop::white" "$desktop::armoricon_mp" "250" ;
			}

		}		
		windowDef icon_armorvest_mp
		{
			rect	424,458,16,16
			visible	1
			background	"gfx/guis/hud/icons/item_armor"
			matcolor	0.980,0.168,0.0196,0.8
		}
	}
	
//-----------------------		
// weapon switching
//-----------------------	

	windowDef p_weapswitch
	{
		rect	0,350,640,80
		visible	0
		notime	1
		
		onNamedEvent UpdateWeapons {
			if ( "gui::weapon0" ) {
				set "ws_weapon0::visible" "1";
				if ( "gui::weapon0_ammo" != 0 ) {
					set "ws_weapon0_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 0 ) {
						set "ws_weapon0_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon0_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon0_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon0_glow::matcolor" "$desktop::ws_glowon";			
					}
				} else {
					set "ws_weapon0_noammo::visible" "1";
					set "ws_weapon0_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon0_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon0::visible" "0";
			}
			
			if ( "gui::weapon1" ) {
				set "ws_weapon1::visible" "1";
				if ( "gui::weapon1_ammo" != 0 ) {
					set "ws_weapon1_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 1 ) {
						set "ws_weapon1_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon1_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon1_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon1_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon1_noammo::visible" "1";
					set "ws_weapon1_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon1_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon1::visible" "0";
			}
			
			if ( "gui::weapon2" ) {
				set "ws_weapon2::visible" "1";
				if ( "gui::weapon2_ammo" != 0 ) {
					set "ws_weapon2_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 2 ) {
						set "ws_weapon2_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon2_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon2_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon2_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon2_noammo::visible" "1";
					set "ws_weapon2_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon2_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon2::visible" "0";
			}
			
			if ( "gui::weapon3" ) {
				set "ws_weapon3::visible" "1";
				if ( "gui::weapon3_ammo" != 0 ) {
					set "ws_weapon3_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 3 ) {
						set "ws_weapon3_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon3_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon3_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon3_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon3_noammo::visible" "1";
					set "ws_weapon3_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon3_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon3::visible" "0";
			}
			
			if ( "gui::weapon4" ) {
				set "ws_weapon4::visible" "1";
				if ( "gui::weapon4_ammo" != 0 ) {
					set "ws_weapon4_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 4 ) {
						set "ws_weapon4_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon4_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon4_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon4_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon4_noammo::visible" "1";
					set "ws_weapon4_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon4_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon4::visible" "0";
			}
			
			if ( "gui::weapon5" ) {
				set "ws_weapon5::visible" "1";
				if ( "gui::weapon5_ammo" != 0 ) {
					set "ws_weapon5_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 5 ) {
						set "ws_weapon5_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon5_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon5_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon5_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon5_noammo::visible" "1";
					set "ws_weapon5_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon5_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon5::visible" "0";
			}
			
			if ( "gui::weapon6" ) {
				set "ws_weapon6::visible" "1";
				if ( "gui::weapon6_ammo" != 0 ) {
					set "ws_weapon6_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 6 ) {
						set "ws_weapon6_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon6_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon6_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon6_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon6_noammo::visible" "1";
					set "ws_weapon6_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon6_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon6::visible" "0";
			}
			
			if ( "gui::weapon7" ) {
				set "ws_weapon7::visible" "1";
				if ( "gui::weapon7_ammo" != 0 ) {
					set "ws_weapon7_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 7 ) {
						set "ws_weapon7_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon7_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon7_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon7_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon7_noammo::visible" "1";
					set "ws_weapon7_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon7_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon7::visible" "0";
			}
			
			if ( "gui::weapon8" ) {
				set "ws_weapon8::visible" "1";
				if ( "gui::weapon8_ammo" != 0 ) {
					set "ws_weapon8_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 8 ) {
						set "ws_weapon8_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon8_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon8_icon::matcolor" "$desktop::ws_on";	
						set "ws_weapon8_glow::matcolor" "$desktop::ws_glowon";					
					}
				} else {
					set "ws_weapon8_noammo::visible" "1";
					set "ws_weapon8_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon8_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon8::visible" "0";
			}					
			
			if ( "gui::weapon9" ) {
				set "ws_weapon9::visible" "1";
				if ( "gui::weapon9_ammo" != 0 ) {
					set "ws_weapon9_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 9 ) {
						set "ws_weapon9_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon9_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon9_icon::matcolor" "$desktop::ws_on";		
						set "ws_weapon9_glow::matcolor" "$desktop::ws_glowon";				
					}
				} else {
					set "ws_weapon9_noammo::visible" "1";
					set "ws_weapon9_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon9_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon9::visible" "0";
			}					

			if ( "gui::weapon10" ) {
				set "ws_weapon10::visible" "1";
				if ( "gui::weapon10_ammo" != 0 ) {
					set "ws_weapon10_noammo::visible" "0";
					if ( "gui::player_idealWeapon" != 10 ) {
						set "ws_weapon10_icon::matcolor" "$desktop::ws_off";
						set "ws_weapon10_glow::matcolor" "$desktop::ws_glowoff";
					} else {
						set "ws_weapon10_icon::matcolor" "$desktop::ws_on";		
						set "ws_weapon10_glow::matcolor" "$desktop::ws_glowon";				
					}
				} else {
					set "ws_weapon10_noammo::visible" "1";
					set "ws_weapon10_icon::matcolor" "$desktop::ws_off";
					set "ws_weapon10_glow::matcolor" "$desktop::ws_glowoff";
				}
			} else {
				set "ws_weapon10::visible" "0";
			}					
		}

		onTime 1000 {
			set "notime" "0";
			set "visible" "0";
			set "desktop::weapswitch" "0";
		}

		windowDef ws_name
		{
			rect	0,42,640,40
			forecolor	0.690,0.784,0.568,1
			textalign	1
			font	"fonts/marine"
			textscale	.25
			textstyle	1
			text	"gui::weaponname"
		}
		
		windowDef ws_weapon0
		{
			rect	("desktop::switchLeft" + "gui::weapon0_index" * 30),20,26,26
			windowDef ws_weapon0_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}
			windowDef ws_weapon0_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon0_icon
			{
				rect	4,4,18,18
				background	"gui::weapon0_icon"
			}
			windowDef ws_weapon0_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon1
		{
			rect	("desktop::switchLeft" + "gui::weapon1_index" * 30),20,26,26
			windowDef ws_weapon1_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}
			windowDef ws_weapon1_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon1_icon
			{
				rect	4,4,18,18
				background	"gui::weapon1_icon"
			}
			windowDef ws_weapon1_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}

		}
		windowDef ws_weapon2
		{
			rect	("desktop::switchLeft" + "gui::weapon2_index" * 30),20,26,26
			windowDef ws_weapon2_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon2_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon2_icon
			{
				rect	4,4,18,18
				background	"gui::weapon2_icon"
			}
			windowDef ws_weapon2_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}

		windowDef ws_weapon3
		{
			rect	("desktop::switchLeft" + "gui::weapon3_index" * 30),20,26,26
			windowDef ws_weapon3_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon3_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon3_icon
			{
				rect	4,4,18,18
				background	"gui::weapon3_icon"
			}
			windowDef ws_weapon3_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon4
		{
			rect	("desktop::switchLeft" + "gui::weapon4_index" * 30),20,26,26
			windowDef ws_weapon4_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon4_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon4_icon
			{
				rect	4,4,18,18
				background	"gui::weapon4_icon"
			}
			windowDef ws_weapon4_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon5
		{
			rect	("desktop::switchLeft" + "gui::weapon5_index" * 30),20,26,26
			windowDef ws_weapon5_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon5_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon5_icon
			{
				rect	4,4,18,18
				background	"gui::weapon5_icon"
			}
			windowDef ws_weapon5_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon6
		{
			rect	("desktop::switchLeft" + "gui::weapon6_index" * 30),20,26,26
			windowDef ws_weapon6_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon6_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}	
			windowDef ws_weapon6_icon
			{
				rect	4,4,18,18
				background	"gui::weapon6_icon"
			}
			windowDef ws_weapon6_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon7
		{
			rect	("desktop::switchLeft" + "gui::weapon7_index" * 30),20,26,26
			windowDef ws_weapon7_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon7_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon7_icon
			{
				rect	4,4,18,18
				background	"gui::weapon7_icon"
			}
			windowDef ws_weapon7_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon8
		{
			rect	("desktop::switchLeft" + "gui::weapon8_index" * 30),20,26,26
			windowDef ws_weapon8_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon8_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon8_icon
			{
				rect	4,4,18,18
				background	"gui::weapon8_icon"
			}
			windowDef ws_weapon8_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon9
		{
			rect	("desktop::switchLeft" + "gui::weapon9_index" * 30),20,26,26
			windowDef ws_weapon9_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon9_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon9_icon
			{
				rect	4,4,18,18
				background	"gui::weapon9_icon"
			}
			windowDef ws_weapon9_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
		windowDef ws_weapon10
		{
			rect	("desktop::switchLeft" + "gui::weapon10_index" * 30),20,26,26
			windowDef ws_weapon10_bg
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbar"
				matcolor	0,0,0,0.5
				shear	0,-.22
			}	
			windowDef ws_weapon10_glow
			{
				rect	0,0,26,26
				background	"gfx/guis/hud/wsbarglow"
				matcolor	0.690,0.784,0.568,0
				shear	0,-.22
			}			
			windowDef ws_weapon10_icon
			{
				rect	4,4,18,18
				background	"gui::weapon10_icon"
			}
			windowDef ws_weapon10_noammo
			{
				rect	4,4,18,18
				background	"gfx/guis/hud/noammo"
				matcolor	1,1,1,1
				visible	0
			}
		}
	}
	
//-----------------------		
// radio messages
//-----------------------		
	
	windowDef p_radio
	{
		rect	0,0,640,480
		visible	1
		windowDef radio_backbar
		{
			rect	520,5,113,28
			visible	1
			background	"gfx/guis/hud_rev3/radiobar"
			matcolor	0,0,0,0.498
			shear	0,-.22
		}
		windowDef t_radio1
		{
			rect	545,6,81,12
			visible	1
			forecolor	1,1,1,1
			text	"#str_200272"
			textscale	0.2
			font	"fonts/marine"
			textspacing	0
		}
		windowDef t_radio2
		{
			rect	545,13,81,12
			visible	1
			forecolor	1,1,1,1
			text	"#str_200273"
			textscale	0.2
			font	"fonts/marine"
			textspacing	0
		}
		windowDef waveform
		{
			rect	513,7,41,25
			visible	1
			background	"gfx/guis/hud/waveform"
			matcolor	1,0.5,0,1
		}
		windowDef rhino_backbar
		{
			rect	468,5,46,47
			background	"gfx/guis/hud/wsbar"
			matcolor	0,0,0,0.4
			shear	0,-.22
			visible	"gui::rhinochatter"
		}
		windowDef rhino
		{
			rect	471,9,42,39
			background	"gfx/guis/hud/radio_rhino"
			visible	"gui::rhinochatter"
			matcolor	1,1,0,1
			notime	1
			shear	0,-.22
		}
		windowDef d_rhino_backbar
		{
			rect	493,6,26,26
			background	"gfx/guis/hud/wsbar"
			matcolor	0,0,0,0.4
			shear	0,-.22
			visible	0
		}
		windowDef d_rhino
		{
			rect	495,8,22,22
			background	"gfx/guis/hud/radio_rhino"
			visible	0
			matcolor	1,1,1,1
			shear	0,-.22
		}
	}

//-----------------------		
// item/ammo pickups
//-----------------------		
	
	windowDef p_itempickup
	{
		rect	0,0,640,480
		visible	0
		notime	1
		
		onTime 3000 {
			set "visible" "0";
		}
		
		windowDef pickup_backbar
		{
			rect	21,401,230,24
			visible	1
			background	"gfx/guis/hud/pickupbar"
			matcolor	0,0,0,0.5
			shear	0,-.22
		}
		windowDef t_pickupname
		{
			rect	42,404,236,15
			visible	1
			forecolor	0.862,0.917,0.760,1
			text	"gui::itemtext"
			textscale	0.2
			font	"fonts/marine"
			textspacing	0
		}
		windowDef icon_pickup
		{
			rect	26,405,16,16
			visible	1
			background	"gui::itemicon"
			matcolor	0.666,0.674,0.435,0.8
		}
	}

//-----------------------		
// powerups
//-----------------------		
		
	windowDef powerups
	{
		rect	520,0,120,480
		visible	("gui::stat_visible" == 0)
		windowDef powerup_flag
		{
			rect	38,435,84,39
			visible	"gui::powerup_flag_visible"
			windowDef powerup_flag_bg
			{
				rect	2,-1,81,42
				background	"gfx/guis/hud/powerup_bgbar"
				visible	1
				matcolor	0,0,0,1
				matscalex	-1
				matscaley	-1
			}
			windowDef powerup_flag_icon
			{
				rect	23,8,22,22
				visible	1
				background	"gfx/guis/hud/ctf_flag"
				matcolor	1,0.482,0.0156,0.8
				shear	0,-.22

				onTime 0 {
					transition "powerup_flag_icon::rect" "$powerup_flag_icon::rect" "$d_powerup_flag_icon::rect" "150" ;
				}

				onTime +150 {
					transition "powerup_flag_icon::rect" "$d_powerup_flag_icon::rect" "$powerup_flag_icon::rect" "500" ;
				}

				onTime +500 {
					resettime "0" ;
				}

			}
			windowDef d_powerup_flag_icon
			{
				rect	20,5,28,28
				visible	0
				background	"gfx/guis/hud/ctf_flag"
				matcolor	1,0.482,0.0156,0.8
				shear	0,-.22
			}
		}
		windowDef powerup4
		{
			rect	37,400,84,38
			visible	"gui::powerup4_visible"
			windowDef powerup4_bg
			{
				rect	2,0,81,42
				background	"gfx/guis/hud/powerup_bgbar"
				visible	1
				matcolor	0,0,0,1
				matscalex	-1
				matscaley	-1
			}
			windowDef powerup4_icon
			{
				rect	21,7,28,28
				visible	1
				background	"gui::powerup4_icon"
				matcolor	1,1,1,1
			}
			windowDef powerup4_time
			{
				rect	48,7,31,25
				visible	1
				text	"gui::powerup4_time"
				forecolor	0.866,0.921,0.764,1
				textscale	0.4
				font	"fonts/chain"
				shear	0,-.22
			}			
		}
		windowDef powerup0
		{
			rect	37,365,84,38
			visible	"gui::powerup0_visible"
			windowDef powerup0_bg
			{
				rect	2,0,81,42
				background	"gfx/guis/hud/powerup_bgbar"
				visible	1
				matcolor	0,0,0,1
				matscalex	-1
				matscaley	-1
			}
			windowDef powerup0_icon
			{
				rect	21,7,28,28
				visible	1
				background	"gui::powerup0_icon"
				matcolor	1,1,1,1
			}
			windowDef powerup0_time
			{
				rect	48,7,31,25
				visible	1
				text	"gui::powerup0_time"
				forecolor	0.866,0.921,0.764,1
				textscale	0.4
				font	"fonts/chain"
				shear	0,-.22
			}
		}
		windowDef powerup1
		{
			rect	37,330,84,38
			visible	"gui::powerup1_visible"
			windowDef powerup1_bg
			{
				rect	2,0,81,42
				background	"gfx/guis/hud/powerup_bgbar"
				visible	1
				matcolor	0,0,0,1
				matscalex	-1
				matscaley	-1
			}
			windowDef powerup1_icon
			{
				rect	21,7,28,28
				visible	1
				background	"gui::powerup1_icon"
				matcolor	1,1,1,1
			}
			windowDef powerup1_time
			{
				rect	48,7,31,25
				visible	1
				text	"gui::powerup1_time"
				forecolor	0.866,0.921,0.764,1
				textscale	0.4
				font	"fonts/chain"
				shear	0,-.22
			}
		}
		windowDef powerup2
		{
			rect	37,295,84,38
			visible	"gui::powerup2_visible"
			windowDef powerup2_bg
			{
				rect	2,0,81,42
				background	"gfx/guis/hud/powerup_bgbar"
				visible	1
				matcolor	0,0,0,1
				matscalex	-1
				matscaley	-1
			}
			windowDef powerup2_icon
			{
				rect	21,7,28,28
				visible	1
				background	"gui::powerup2_icon"
				matcolor	1,1,1,1
			}
			windowDef powerup2_time
			{
				rect	48,7,31,25
				visible	1
				text	"gui::powerup2_time"
				forecolor	0.866,0.921,0.764,1
				textscale	0.4
				font	"fonts/chain"
				shear	0,-.22
			}
		}
		windowDef powerup3
		{
			rect	37,260,84,38
			visible	"gui::powerup3_visible"
			windowDef powerup3_bg
			{
				rect	2,0,81,42
				background	"gfx/guis/hud/powerup_bgbar"
				visible	1
				matcolor	0,0,0,1
				matscalex	-1
				matscaley	-1
			}
			windowDef powerup3_icon
			{
				rect	21,7,28,28
				visible	1
				background	"gui::powerup3_icon"
				matcolor	1,1,1,1
			}
			windowDef powerup3_time
			{
				rect	48,7,31,25
				visible	1
				text	"gui::powerup3_time"
				forecolor	0.866,0.921,0.764,1
				textscale	0.4
				font	"fonts/chain"
				shear	0,-.22
			}
		}
	}
	
//-----------------------		
// interactive gui brackets
//-----------------------		
	
	windowDef brackets
	{
		visible	0
		rect	"gui::bracket_left" - 10, "gui::bracket_top" - 10, "gui::bracket_width" + 20, "gui::bracket_height" + 20
		noclip	1
		notime	1
		float	"alpha"	1

		onTime 400 {
			transition "brackets::alpha" "1" "0" 400;
		}

		onTime +400 {
			set "visible" "0";
		}

		windowDef bracket_text
		{
			rect	-50,-30,"gui::bracket_width"+120,30
			text	"#str_200277"
			font	"fonts/marine"
			textalign	1
			forecolor	0.686,0.870,0.564,"brackets::alpha"
			textscale	.25
		}
		windowDef left_bracket
		{
			rect	0,0,2,"gui::bracket_height" + 20
			backcolor	0.686,0.870,0.564,"brackets::alpha"
			noclip	1
			windowDef lbt_prong
			{
				rect	2,0,5,2
				backcolor	0.686,0.870,0.564,"brackets::alpha"
			}
			windowDef lbb_prong
			{
				rect	2,"gui::bracket_height"+18,5,2
				backcolor	0.686,0.870,0.564,"brackets::alpha"
			}
		}
		windowDef right_bracket
		{
			rect	"gui::bracket_width" + 18,0,2,"gui::bracket_height" + 20
			backcolor	0.686,0.870,0.564,"brackets::alpha"
			visible	1
			noclip	1
			windowDef rbt_prong
			{
				rect	-5,0,5,2
				backcolor	0.686,0.870,0.564,"brackets::alpha"
			}
			windowDef rbb_prong
			{
				rect	-5,"gui::bracket_height"+18,5,2
				backcolor	0.686,0.870,0.564,"brackets::alpha"
			}
		}
	}	

//-----------------------		
// boss bar
//-----------------------
	
	windowDef Bossbar
	{
		rect	-20,0,640,480
		visible	0
		windowDef boss_backbar
		{
			rect	240,40,200,50
			visible	1
			background	"gfx/guis/hud/s_bossbar"
			matcolor	0,0,0,0.5
		}
		windowDef boss_healthicon
		{
			rect	334,75,12,12
			visible	1
			background	"gfx/guis/hud/icons/item_health"
			matcolor	1,1,1,0.2
		}
		windowDef boss_health_bar2
		{
			rect	239,40,200,50
			visible	1
			background	"gfx/guis/hud/s_boss_healthbar"
			matcolor	0.917,0.560,0.0823,0.2
		}
		windowDef boss_shield_bar_left2
		{
			rect	240,40,100,50
			visible	1
			background	"gfx/guis/hud/s_boss_shieldbar"
			matcolor	0.415,0.549,0.541,0.2
		}
		windowDef boss_shield_bar_right2
		{
			rect	340,40,100,50
			visible	1
			background	"gfx/guis/hud/s_boss_shieldbar"
			matcolor	0.415,0.549,0.541,0.2
			matscalex	-1
		}
		windowDef p_boss_health_bar
		{
			rect	266,40,149 * "gui::boss_health" / ("gui::boss_maxhealth" + 1),50
			visible	1
			windowDef boss_health_bar
			{
				rect	-26,0,200,50
				visible	1
				background	"gfx/guis/hud/s_boss_healthbar"
				matcolor	0.917,0.560,0.0823,0.35
			}
		}
		windowDef p_boss_shield_bar_left
		{
			rect	250,40,89 * "gui::boss_shield_percent",50
			visible	0
			windowDef boss_shield_bar_left
			{
				rect	-10,0,100,50
				visible	1
				background	"gfx/guis/hud/s_boss_shieldbar"
				matcolor	0.415,0.549,0.541,0.35
			}
		}
		windowDef p_boss_shield_bar_right
		{
			rect	341 + 89 * ( 1 - "gui::boss_shield_percent" ),40,89,50
			visible	0
			windowDef boss_shield_bar_right
			{
				rect	-90 * ( 1 - "gui::boss_shield_percent" ),0,100,50
				visible	1
				background	"gfx/guis/hud/s_boss_shieldbar"
				matcolor	0.415,0.549,0.541,0.35
				matscalex	-1
			}
		}
		windowDef p_boss_shield_bar_leftwarn
		{
			rect	250,40,89 * "gui::boss_shield_percent",50
			visible	0
			windowDef boss_shield_bar_leftwarn
			{
				rect	-9,0,100,50
				visible	1
				background	"gfx/guis/hud/s_boss_shieldbar"
				matcolor	1,0.25,0,1*guitable_10_5[time*0.002]
			}
		}
		windowDef p_boss_shield_bar_rightwarn
		{
			rect	341 + 89 * ( 1 - "gui::boss_shield_percent" ),40,89,50
			visible	0
			windowDef boss_shield_bar_rightwarn
			{
				rect	-90 * ( 1 - "gui::boss_shield_percent" ),0,100,50
				visible	1
				background	"gfx/guis/hud/s_boss_shieldbar"
				matcolor	1,0.25,0,1*guitable_10_5[time*0.002]
				matscalex	-1
			}
		}
	}

//-----------------------		
// missile indicator
//-----------------------

	windowDef missile_indicator
	{
		rect	0,0,640,480
		background	"gfx/guis/hud/directional_hit2"
		matcolor	1,.1,.1,.7
		rotate	"gui::missiledir"
		visible	0
		notime	1

		onTime 0 {
			transition "matcolor_w" "0.7" "0.3" "200" ;
		}

		onTime +200 {
			transition "matcolor_w" "0.3" "0.7" "200" ;
		}

		onTime +400 {
			resettime "0" ;
		}

	}
	windowDef missile_text
	{
		rect	0,61,640,33
		visible	0
		notime	1
		forecolor	1,.1,.1,.7
		text	"#str_200891"
		textscale	0.4
		font	"fonts/marine"
		textalign	1
		textspacing	-2

		onTime 0 {
			transition "forecolor_w" "0.7" "0.3" "200" ;
		}

		onTime +200 {
			transition "forecolor_w" "0.3" "0.7" "200" ;
		}

		onTime +400 {
			resettime "0" ;
		}

	}

//-----------------------		
// exit level status
//-----------------------

	windowDef p_exit_level
	{
		rect	0,0,640,75
		visible	0
		windowDef p_exit_text
		{
			rect	225,36,199,26
			visible	1
			forecolor	1,0.4,0,1
			text	"#str_200013"
			textscale	0.4
			font	"fonts/marine"
			textalign	1
		}
		windowDef p_exit_arr1
		{
			rect	261,11,130,33
			visible	1
			background	"gfx/guis/common/arrow5"
			matcolor	1,0.4,0,0.5
			matscaley	-1

			onTime 0 {
				transition "matcolor_w" ".5" "0" "1000" ;
				transition "rect" "$p_exit_arr1::rect" "$p_exit_arr2::rect" "1000" "300" "300"  ;
			}

			onTime 1000 {
				resettime "0" ;
			}

		}
		windowDef p_exit_arr2
		{
			rect	261,0,130,33
			visible	0
			background	"gfx/guis/common/arrow5"
			matcolor	1,1,1,1
			matscaley	-1
		}
	}
	
//-----------------------		
// quicksave notice
//-----------------------

	windowDef quicksave_msg
	{
		rect	0,64,640,20
		visible	0
		forecolor	1,1,1,1
		text	"#str_200908"
		textscale	0.25
		font	"fonts/lowpixel"
		textspacing	0
		textalign	1
		textstyle	1

		onTime 2000 {
			transition "forecolor_w" "1" "0" "1000" ;
		}
		
		onTime +1000 {
			set "quicksave_msg::visible" "0" ;
		}

	}

//-----------------------		
// hit indicator
//-----------------------	

	windowDef hit_indicator
	{
		rect		0,0,640,480
		background	"gfx/guis/hud/directional_hit"
		matcolor	1,.1,.1,.7
		rotate		"gui::hitdir"
		visible		0
		notime		1
		
		onTime 0 
		{
			set "visible" "1";
			transition "matcolor" "1,.1,.1,.7" "1,.1,.1,0" "500" ;
		}
		
		onTime +600
		{
			set "visible" "0";
		}
	}
	
//-----------------------		
// over top black/failed text
//-----------------------	
	
		windowDef fade
		{
			rect	0,0,640,480
			backcolor	0,0,0,0
			visible	1
		}	
		
		windowDef failedtext
		{
			rect	0,220,640,20
			visible	1
			forecolor	1,1,1,0
			text	"#str_200279"
			textscale	0.5
			font	"fonts/marine"
			textalign	1
		}	
	
//-----------------------		
// animations
//-----------------------		
	
	windowDef anim_fade
	{
		rect	0,0,1,1
		visible	1
		notime	1

		onTime 0 {
			transition "fade::backcolor" "0,0,0,0" "0,0,0,1" "3000" ;
		}
		
		onTime 3000 {
			transition "failedtext::forecolor" "1,1,1,0" "1,1,1,1" "250" ;
		}
	}	
	
	windowDef anim_levelExitAlert
	{
		rect	0,0,0.1,0.1
		visible	0
		notime	1
		
		onTime 5000	{
			set "p_exit_level::visible" "0";
		}
	}

//-------------------------

}